uso del signo @ en fórmulas de Excel

La intersección implícita existe en Excel desde hace años, pero a muy poca gente le importaba. Ahora que ya no es el comportamiento predeterminado en Excel 365, surgen muchas preguntas. Este tutorial tiene como objetivo explicar el significado del signo @ en las fórmulas de Excel, que se denomina operador de intersección implícito.

Tienes la sensación de que sabes todo sobre tus libros de trabajo y luego aparece un carácter @ de la nada al comienzo de tus fórmulas. ¿Qué quiere decir esto? ¿Y cómo funciona exactamente? En pocas palabras, es un operador de intersección implícito que deshabilita el nuevo comportamiento de matriz predeterminado de una fórmula y le dice a Excel que devuelva un valor único. Para obtener más detalles, continúe leyendo.

Intersección implícita de Excel

intersección implícita en Excel significa reducir varios valores a un solo valor. Normalmente, ocurre cuando se proporciona una matriz o rango a una fórmula que se supone debe generar solo un valor en una sola celda.

Intersección implícita en Excel 2019 – 2000

En Excel tradicional, la intersección implícita es el comportamiento predeterminado. Se realiza silenciosamente en segundo plano para todas las fórmulas. La lógica de intersección implícita es la siguiente:

• Si la fórmula produce una valor únicodevuelve ese valor (de hecho, la intersección implícita no hace nada en este caso).
• En caso de un rangouse un valor de la celda en la misma fila o columna que la fórmula.
• En caso de un formaciónutilice el valor superior izquierdo.

Por ejemplo, al multiplicar dos columnas de números, Excel elige solo un número de cada columna en la misma fila donde está la fórmula y genera el resultado solo en una celda (D2 en nuestro caso):

=B2:B5*C2:C5

Para multiplicar los números en otras celdas, debes copiar la fórmula.
>

A desactivar la intersección implícitadebes ingresar una fórmula matricial con Ctrl + Mayús + Intro (Es por eso que las fórmulas de matriz tradicionales a veces se llaman Fórmulas CSE). Esto le indica claramente a Excel que procese la entrada de múltiples valores como rangos o matrices.

En nuestro caso, seleccione las celdas D2:D5, escriba la fórmula anterior y confírmela presionando el botón Ctrl + Mayús + Intro llaves juntas. Una vez que haga esto, la fórmula quedará rodeada por {llaves}, lo que indica que es una fórmula matricial. Como resultado, los números de cada fila se multiplican a la vez:

>Intersección implícita en Excel 365

La introducción de matrices dinámicas ha cambiado el comportamiento predeterminado de todas las fórmulas en Excel 365. Ahora, cualquier fórmula que potencialmente pueda producir múltiples resultados, los derrama automáticamente en la hoja. Eso hace que la intersección implícita sea innecesaria, y es ya no se activa de forma predeterminada. Por este motivo, a veces se denomina Excel 365 matriz dinámica excel o DA Excel.

Aquí, los rangos completos se multiplican con una fórmula regular que solo se ingresa en la celda superior (D2):

=B2:B5*C2:C5

El resultado es un rango de derrames que consta de 4 celdas:
>

Si desea que una fórmula devuelva solo un valor, debe especificar explícitamente permitir la interceptación implícita. Para ello, introdujeron un operador especial, y en la siguiente sección encontrarás todos los detalles al respecto.

Operador de intersección implícito: signo @ en fórmulas de Excel

El operador de intersección implícito se introdujo en Excel 365 para evitar el comportamiento predeterminado de la matriz dinámica. Si desea que una fórmula devuelva solo un valor, coloque @ antes del nombre de la función (o antes de un cierto rango o matriz dentro de la fórmula) y se comportará como una fórmula normal sin matriz en las versiones predinámicas.

Por ejemplo:

=@B2:B5*@C2:C5
>

¿Por qué se agrega @ a las fórmulas antiguas?

En Excel 365, es posible que observe que se agrega el carácter @ a algunas de sus fórmulas al abrir un libro creado en una versión anterior. En su mayor parte, se hace para forzar que una fórmula se comporte de la misma manera que en la versión original en la que se creó. En otras palabras, si una fórmula devolvió un valor único en una versión anterior pero devolvió múltiples resultados en Excel 365, automáticamente tendrá el prefijo @ para desactivar el comportamiento de matriz.

Normalmente, el operador de intersección se inserta antes de la función que podría devolver matrices o rangos de varias celdas, como DESPLAZAMIENTO, ÍNDICE o funciones definidas por el usuario.

Por ejemplo, la siguiente fórmula creada en Excel predinámico:

=INDEX(B2:C5,,F1)

tomará la siguiente forma en una matriz dinámica de Excel:

=@INDEX(B2:C5,,F1)

La razón es que sin el operador @, la fórmula devolverá todos los valores de C2:C5 porque el número_fila Se omite el argumento de la función ÍNDICE. Para garantizar un comportamiento coherente en todas las versiones, la intersección implícita que antes era imperceptible se vuelve evidente. Por favor compare los resultados:
>

En caso de que una función con una posible salida de varias celdas esté anidada en otra que pueda manejar matrices y generar un único resultado (como SUMA, CONTEO, PROMEDIO, etc.), entonces no hay razón para activar la intersección implícita, y la La fórmula se transfiere a Excel dinámico tal como está sin agregar el signo @. Por ejemplo:

=AVERAGE(INDEX(B2:C5,,F1))

>¿Puedo eliminar el símbolo @ de mis fórmulas?

Seguro que puede. Excel realiza la conversión de fórmulas solo una vez. Si el operador @ interrumpe o cambia negativamente el comportamiento de sus fórmulas, puede eliminar @ manualmente y no volverá a aparecer después de guardar el libro.

¿Cuáles son las consecuencias de eliminar el operador de intersección implícito? Dependiendo de lo que devuelva la parte de la fórmula que sigue al signo @, hay tres resultados posibles:

• si un valor único es devuelto, no habrá ningún cambio.
• Si una formación se devuelve, se derramará en las celdas adyacentes.
• Si se devuelve una matriz pero hay no hay suficientes celdas vacías para mostrar todos los valores, se producirá un error #SPILL.

¿Por qué utilizar el operador @ en Excel 365?

Como ya se mencionó, Excel para Microsoft 365 trata todas las fórmulas como fórmulas de matriz de forma predeterminada, sin que usted tenga que presionar Ctrl + Mayús + Intro como solías hacer en las versiones anteriores. Si desea deshabilitar el comportamiento de la matriz, inserte el operador de intersección implícito.

Ejemplo 1. ¡Deshazte del #DERRAME! error

Un escenario muy común es prevenir o corregir errores #SPILL. Si le resulta conveniente hacer referencia a columnas enteras (lo cual generalmente no es una muy buena idea porque ralentiza Excel), pero aún así dicha fórmula funcionará bien en versiones predinámicas:

=VLOOKUP(A:A, D:E, 2, FALSE)

En Excel dinámico, se producirá un error #SPILL porque no hay suficiente espacio para mostrar casi 1,05 millones de resultados.

Agregar @ antes del argumento valor_buscado resuelve el problema:

=VLOOKUP(@A:A, D:E, 2, FALSE)
>

Cuando Excel prevea que la fórmula puede extenderse más allá de los bordes de la hoja de cálculo, sugerirá una corrección y sería prudente aceptarla:

>Ejemplo 2. Hacer que la fórmula funcione correctamente en Excel anterior

Si está utilizando una suscripción a Microsoft 365 y comparte sus archivos con alguien que se queda con una versión anterior, es importante garantizar un comportamiento de fórmula coherente para todos.

Suponga que ha escrito esta fórmula de matriz dinámica en Excel 365:

=B2:B5*C2:C5

En versiones anteriores, se convertirá a una fórmula matricial CSE heredada:

{=B2:B5*C2:C5}

y devolver un rango de valores en ambos casos:
>

Si desea generar solo un resultado, agregue @ antes de cada expresión y luego copie la fórmula en tantas celdas como sea necesario (para mantener los rangos sin cambios, recuerde bloquearlos con referencias absolutas de celdas):

=@$B$2:$B$5*@$C$2:$C$5

En Excel anterior, el símbolo @ se eliminará automáticamente y la fórmula tendrá un aspecto normal:

=$B$2:$B$5*$C$2:$C$5
>

Lo que no debes hacer es mezclar intersección implícita y cálculos de matriz ¡dentro de una fórmula! Por ejemplo, si intentas ingresar algo como esto en Excel 365:

=@B2:B5*C2:C5

Se le notificará que dicha fórmula no es compatible con versiones anteriores:
>

Si rechaza la variación propuesta, la fórmula mixta se comprometerá y arrojará algunos resultados (aunque es posible que no sean los resultados que esperaba). Pero cuando abre esa fórmula en Excel predinámico, aparecerá la función _xlfn.SINGLE en lugar del operador de intersección implícito:

=_xlfn.SINGLE(B2:B5)*C2:C5

Cuando esta fórmula es evaluada por Excel anterior, aparece un #¡NOMBRE! Se devolverá el error.

Intersección implícita en tablas de Excel

En términos generales, el comportamiento de intersección implícito en las tablas es coherente con su versión de Excel.

En Excel 2019 y anteriorespuede hacer referencia a una columna completa y la fórmula se resolverá en una sola celda de la fila actual.

Por ejemplo, esta fórmula multiplica con éxito los números en el Precio y Cant. columnas:

=[Price]*[Qty.]

Aunque se refiere a las columnas completas, el Excel predinámico todavía opera con valores únicos a nivel de fila.
>

En excel 365, este enfoque no funcionará porque la intersección implícita está desactivada de forma predeterminada. Debido a que la fórmula devuelve múltiples valores y Excel no puede incluirlos todos en una tabla, sugerirá anteponer los nombres de las columnas con el símbolo @:
>

Si tiene experiencia con referencias de tablas, esta sintaxis le resultará familiar: el símbolo @ indica que la fórmula procesará los valores de las columnas. Precio y Cant. en la misma fila.

=[@Price]*[@[Qty.]]

Y funcionará muy bien en todas las versiones:
>

Así es como funciona la intersección implícita en Excel. ¡Te agradezco por leer y espero verte en nuestro blog la próxima semana!

Usted también podría estar interesado en: